隐藏文件夹attrib 命令详解

bush911

attrib命令详解：

语法

attrib [{+r | -r}] [{+a | -a}] [{+s | -s}] [{+h | -h}]
attrib [[Drive:][Path] FileName] [/s[/d]]

参数

+r 设置只读文件属性。
-r 清除只读文件属性。
+a 设置存档属性。
-a 清除存档属性。
+s 设置系统文件属性。
-s 清除系统文件属性。
+h 设置隐藏文件属性。
-h 清除隐藏文件属性。
/s 将 attrib 和任意命令行选项应用到当前目录及其所有子目录中的匹配文件。
/d 将 attrib 和任意命令行选项应用到目录。
/? 在命令提示符下显示帮助。

如想把 “D:\123” 文件夹改为系统文件并隐藏，就在cmd中输入attrib +h +s D:\123 /s /d。

下面这个批处理可以修改磁盘或文件或文件夹内包括隐藏系统文件的系统属性和隐藏属性,很方便的.
复制以下内容到记事本(开始-附件-记事本),另存为"修改系统属性和隐藏属性.bat",保存类型选所有文件.
用的时候,把要修改属性的磁盘或文件或文件夹,拖到批处理文件的图标上(可以拖很多),然后按提示操作就行了.
注意:请把要更改属性的磁盘或文件或文件夹拖到批处理文件图标内,不要双击运行此批处理.

@echo off&setlocal enableextensions enabledelayedexpansion
title 修改系统文件属性和隐藏文件属性&color 0!random:~-1!&color 0!random:~-1!
if "%~1"=="" (echo 你没有拖入 任何磁盘或文件或文件夹
echo 请把 要处理的磁盘或文件或文件夹 拖到 批处理文件图标
echo 不要 双击启动 批处理&pause&goto :eof)
call:choose "设置隐藏文件属性,请选择:" 不改变 减隐藏文件属性 加隐藏文件属性
(set h=)&(if !c! equ 2 set h=-)&(if !c! equ 3 set h=+)
call:choose "设置系统文件属性,请选择:" 不改变 减系统文件属性 加系统文件属性
(set s=)&(if !c! equ 2 set s=-)&(if !c! equ 3 set s=+)
call:choose "设置应用范围,请选择:" 所选文件和文件夹 该容器内的文件和文件夹
for %%i in (%*) do (if !c! equ 1 call:attrib "%%~i"
for /f "delims=" %%j in ('dir /a /b "%%~i"') do call:attrib "%%~i\%%~j")
pause&goto :eof
:choose
(set c=)&(set n=)&for %%i in (%*) do echo !n! %%~i&set /a n+=1
(set /p c=)&(set /a c=c)&if !c! geq 0 if !c! leq !n! echo.&goto :eof
goto choose
:attrib
setlocal&(set a=)&(set a=%~a1)&if "!a!"=="" goto :eof
if not defined h if "!a:~3,1!"=="h" (set h=+) else (set h=-)
if not defined s if "!a:~4,1!"=="s" (set s=+) else (set s=-)
echo 正在处理: %~1&attrib !h!h !s!s "%~1"&goto :eof